MPLUS

RMLCA MPLUS Code

MPLUS Input Code for a Conditional RMLCA Model (model with covariates) with a Dichotomous Distal Outcome

Annotations appear in green. Text that appears in blue contains information specific to our study (i.e., our variable names). This input file specifies a 5-class solution with covariates (FTND score, number of past quit attempts, longest number of days abstinent, quitting self-efficacy, baseline sleep disturbance, racial minority status, 5 treatment contrast variables) and a distal outcome (6-month point-prevalence abstinence).

The data file for this code needs to be a wide file in csv format, in which the repeated measures appear as separate columns rather than as separate rows in the data file.

DATA:
FILE IS filename.csv;

VARIABLE:
NAMES ARE
ID Smok1-Smok27
ftndtot lnquit20 daysabp success wswsslp minority 
txVsPBO PatLozVsTx PatBupLozVSBup_Loz PatVsBupLoz BupVsLoz 
Zftndtot Zsuccess Zlnquit20 Zdaysabp Zwswsleep ppab6mo;

USEVARIABLES ARE smok1-smok27 minority Zwswsleep Zftndtot Zsuccess Zlnquit20 Zdaysabp
txVsPBO PatLozVsTx PatBupLozVSBup_Loz PatVsBupLoz BupVsLoz;

!DEFINE CATEGORICAL INDICATORS
CATEGORICAL ARE smok1-smok27;

!DEFINE # OF CLASSES
CLASSES are C(5);

!INCLUDE DISTAL OUTCOME WITH DE3STEP COMMAND FOR CATEGORICAL DISTAL OUTCOMES
AUXILIARY ARE ppab6mo(de3step);

!DEFINE MISSING DATA CODE
MISSING ARE ALL(999);

ANALYSIS:

!ESTIMATE A MIXTURE MODEL
TYPE = MIXTURE;

!DEFINE MULTIPLE RANDOM STARTS
STARTS = 1000 500;

MODEL:
%OVERALL%

!REGRESS CLASS ON COVARIATES
C on minority txVsPBO PatLozVsTx PatBupLozVSBup_Loz PatVsBupLoz BupVsLoz 
Zftndtot Zsuccess Zlnquit20 Zdaysabp Zwswsleep;

%C#1%
[smok1$1-smok27$1*];
%C#2%
[smok1$1-smok27$1*];
%C#3%
[smok1$1-smok27$1*];
%C#4%
[smok1$1-smok27$1*];
%C#5%
[smok1$1-smok27$1*];

OUTPUT:
!TECH11 PROVIDES LMR-LRT (Lo-Mendell-Rubin Likelihood Ratio Test) and TECH14 PROVIDES BLRT (Bootstrap Likelihood Ratio Test)
SAMPSTAT STANDARDIZED TECH1 TECH4 TECH11 TECH14;